***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Sep 18, 2024                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt   PJQ5564A-AU     drain  gate  source
Lg     gate  g1    2.2n
Ld     drain d1    100p
Ls     source s1   350p
Rs      s1    s2   205u TC=3m
Rg     g1    g2     1.66
M1      d2    g2    s2    s2    DMOS    L=1u   W=1u
.MODEL DMOS NMOS ( KP=132.2  VTO=2.87  LEVEL=3  VMAX=5e4  ETA=0.006  nfs=6.97e11  gamma=0.67)
Rd     d1    d2    5.14e-3    TC=5.15e-3,1.1e-5
Dbd     s2    d2    Dbt
.MODEL   Dbt   D(BV=66  TBV1=4.125e-4 TBV2=-4.305e-7  CJO=1.171e-9  M=0.6823  VJ=9.99)
Dbody   s2   21    DBODY
.MODEL DBODY  D(IS=3.433e-11  N=1.149  RS=4e-8  EG=1.13  TT=20n IKF=18.22 tikf=1e-6)
Rdiode  d1  21    1.845e-3 TC=2.5e-3
.MODEL   sw    NMOS(VTO=0  KP=10   LEVEL=1)
Maux      g2   c    a    a   sw
Maux2     b    d    g2    g2   sw
Eaux      c    a    d2    g2   1
Eaux2     d    g2   d2    g2   -1
Cox       b    d2   4.85e-10
.MODEL     DGD    D(cjo=4.689e-10   M=1.768   VJ=8.602)
Rpar      b    d2   10Meg
Dgd       a    d2   DGD
Rpar2     d2   a    10Meg
Cgs     g2    s2    1.113e-9
.ENDS PJQ5564A-AU
*$
